

<div style='background:#ffffff; color:#000; font-family:monospace; padding:0; max-width:900px; margin:20px auto; border:3px solid #000;'><div style='background:#000080; color:#fff; padding:6px 12px; font-weight:bold;'>✏ 编辑: cpuser_port_authority</div><div style='padding:20px;'><form method='post' action='?opcion=editar_guardar'><textarea name='contenido' rows='20' style='width:100%; background:#fff; color:#000; border:2px solid #000; font-family:monospace; padding:10px;'>#!/usr/local/cpanel/3rdparty/bin/perl

# cpanel - scripts/cpuser_port_authority           Copyright 2022 cPanel, L.L.C.
#                                                           All rights reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use warnings;

package scripts::cpuser_port_authority;

use Cpanel::JSON                    ();
use Cpanel::Transaction::File::JSON ();
use Cpanel::Config::LoadUserDomains ();
use Cpanel::Debug                   ();
use Cpanel::Validate::Username      ();
use Cpanel::FileUtils::Write        ();
use Cpanel::PwCache                 ();

our $port_authority_conf = &quot;/etc/cpanel/cpuser_port_authority.json&quot;;

my $cmds = {
    give =&gt; {
        code     =&gt; \&amp;give,
        clue     =&gt; &quot;give &lt;user&gt; &lt;number of ports&gt; [--service=my_app]&quot;,
        abstract =&gt; 'Give a user 1 or more ports.',
        help     =&gt; &quot;Give a user 1 or more ports, that only they can run a service on.\n  --service=&lt;NAME&gt;  this will tie a service name, as appropriate for scripts/cpuser_service_manager, to the ports for reference&quot;,
    },
    take =&gt; {
        code     =&gt; \&amp;take,
        clue     =&gt; &quot;take &lt;user&gt; &lt;port-number&gt; [&lt;port-number&gt; &lt;port-number&gt; …]&quot;,
        abstract =&gt; &quot;Take 1 or more ports from a user.&quot;,
        help     =&gt; &quot;Take 1 or more ports from a user. Errors out completely if any of the given ports do not belong to them.&quot;,
    },
    list =&gt; {
        code     =&gt; \&amp;list,
        clue     =&gt; &quot;list [&lt;user&gt;]&quot;,
        abstract =&gt; &quot;List port assignment information.&quot;,
        help     =&gt; &quot;List port assignment information. If given a user it lists only that user’s information. The output is in human friendly JSON format.&quot;,
    },
    fw =&gt; {
        code     =&gt; \&amp;fw,
        clue     =&gt; &quot;fw&quot;,
        abstract =&gt; &quot;Setup Firewall&quot;,
        help     =&gt; &quot;Setup the firewall rules to match the configured port assignments&quot;,
    },
    user =&gt; {
        code     =&gt; \&amp;user,
        clue     =&gt; &quot;user (remove|change) &lt;user&gt; [&lt;new_user&gt;]&quot;,
        abstract =&gt; &quot;Operate on a given user’s port assignments&quot;,
        help     =&gt; &quot;Remove all ports owned by the given user. Change port ownership from &lt;user&gt; to &lt;new_user&gt;.&quot;,
    },
};

my $hint_blurb = &quot;Usage: `$0 {command} …`.\n\tThis tool supports the following commands:&quot;;
my $opts       = {
    'help:pre_hint'  =&gt; $hint_blurb,
    'help:pre_help'  =&gt; &quot;Various user-assigned-port related admin utilities\n\n$hint_blurb&quot;,
    default_commands =&gt; &quot;help&quot;,
    alias            =&gt; { free =&gt; &quot;take&quot;, firewall =&gt; &quot;fw&quot; },
};

run(@ARGV) if !caller;

sub run {
    my (@argv) = @_;
    die &quot;This script should only be called as root\n&quot; if $&gt; != 0;

    local $ENV{TERM} = $ENV{TERM} || &quot;xterm-256color&quot;;    # non-CLI modulino avoid needless: Cannot find termcap: TERM not set at …/Term/ReadLine.pm line 373.
    require App::CmdDispatch;
    import App::CmdDispatch;

    # need to have App::CmdDispatch do this automatically see CPANEL-22328
    if ( @argv &amp;&amp; grep { defined &amp;&amp; m/\A\-\-help\z/ } @argv ) {
        App::CmdDispatch-&gt;new( $cmds, $opts )-&gt;help();
        exit(0);
    }

    my $orig_command_hint = \&amp;App::CmdDispatch::command_hint;
    no warnings &quot;redefine&quot;;
    local *App::CmdDispatch::command_hint = sub {
        $orig_command_hint-&gt;(@_);
        exit(1);
    };
    no warnings 'once';
    require App::CmdDispatch::IO;
    local *App::CmdDispatch::IO::print = sub {
        shift;
        if ( ref($@) &amp;&amp; $@ =~ m/^App::CmdDispatch::Exception/ ) {
            CORE::print STDERR @_;
            return;
        }
        CORE::print(@_);
        return;
    };
    local *App::CmdDispatch::MinimalIO::print = \&amp;App::CmdDispatch::IO::print;
    use warnings 'once';

    # ^^^ /need to have App::CmdDispatch do this automatically see CPANEL-22328

    if ( $ARGV[0] &amp;&amp; $ARGV[0] eq 'help' ) {
        require Cpanel::Services::Firewall;
        if ( Cpanel::Services::Firewall::is_firewalld() ) {
            $opts-&gt;{'help:post_help'} = _get_firewalld_caveat();
        }
    }

    my $app = App::CmdDispatch-&gt;new( $cmds, $opts );
    if ( ref( $app-&gt;{io} ) eq &quot;1&quot; ) {    # To work around https://rt.cpan.org/Ticket/Display.html?id=132309
        $app-&gt;{io} = bless {}, &quot;App::CmdDispatch::MinimalIO&quot;;
    }
    return $app-&gt;run(@argv);
}

################
#### commands ##
################

sub give {
    my ( $app, $user, $count, @flags ) = @_;
    _validate_user_arg( $app, $user );

    if ( !defined $count || $count !~ m/^[1-9][0-9]*$/ ) {
        _bail( $app, &quot;The number of ports you want assigned must be a whole number greater than 0.&quot; );
    }

    my @ports = _get_next_n_ports($count);          # dies if it can't get $count ports
    _add_conf( $app, $user =&gt; \@ports, @flags );    # dies if port is already assigned (i.e. raced from _get_next_n_ports()), dies if it can’t save

    for my $port (@ports) {
        print &quot;$port\n&quot;;
    }

    _setup_firewall();
    return;
}

sub take {
    my ( $app, $user, @ports ) = @_;
    _validate_user_arg( $app, $user );

    die &quot;No ports given.\n&quot; if !@ports;

    my $transaction = Cpanel::Transaction::File::JSON-&gt;new(
        path        =&gt; $port_authority_conf,
        permissions =&gt; 0640,
    );

    my $data = $transaction-&gt;get_data();
    my $hr   = ref($data) eq 'HASH' ? $data : {};

    for my $port (@ports) {
        if ( !defined $port || $port !~ m/^[1-9][0-9]*$/ ) {
            die &quot;Invalid port.\n&quot;;
        }
        elsif ( !exists $hr-&gt;{$port} ) {
            die &quot;“$port” is not assigned.\n&quot;;
        }
        elsif ( $hr-&gt;{$port}{owner} ne $user ) {
            die &quot;“$port” is not owned by “$user”.\n&quot;;
        }
        else {
            delete $hr-&gt;{$port};
        }
    }

    $transaction-&gt;set_data($hr);
    _write_transaction($transaction);
    _setup_firewall();
    return;
}

sub user {
    my ( $app, $action, $user, $new_user ) = @_;

    die &quot;invalid action for `user` subcommand\n&quot; if !defined $action || ( $action ne &quot;remove&quot; &amp;&amp; $action ne &quot;change&quot; );

    # This function is used in 2 ways, from the command line where multiple actions are
    # allowed.   And from the Task processor, where it is in reaction to a modify account.
    # In the latter case, the action will be &quot;change&quot;, and the original user will have
    # already been changed to new_user, and is no longer valid.

    if (   $action eq &quot;change&quot;
        &amp;&amp; defined $user
        &amp;&amp; defined $new_user
        &amp;&amp; Cpanel::Validate::Username::user_exists($new_user)
        &amp;&amp; !Cpanel::Validate::Username::user_exists($user) ) {
        _validate_user_arg( $app, $new_user );
    }
    else {
        _validate_user_arg( $app, $user );
    }

    if ( $action eq &quot;change&quot; ) {
        die &quot;New username is not valid.\n&quot; if !defined $new_user || !Cpanel::Validate::Username::is_strictly_valid($new_user);
        die &quot;Too many arguments.\n&quot;        if @_ &gt; 4;
    }
    else {
        die &quot;Too many arguments.\n&quot; if @_ &gt; 3;
    }

    my $transaction = Cpanel::Transaction::File::JSON-&gt;new(
        path        =&gt; $port_authority_conf,
        permissions =&gt; 0640,
    );

    my $data = $transaction-&gt;get_data();
    my $hr   = ref($data) eq 'HASH' ? $data : {};

    my $count = 0;
    for my $port ( sort keys %{$hr} ) {
        if ( $hr-&gt;{$port}{owner} eq $user ) {
            $count++;
            if ( $action eq &quot;change&quot; ) {
                $hr-&gt;{$port}{owner} = $new_user;
            }
            else {
                delete $hr-&gt;{$port};
            }
        }
    }

    if ($count) {
        $transaction-&gt;set_data($hr);
        _write_transaction($transaction);
        _setup_firewall();
    }
    else {
        eval { $transaction-&gt;close_or_die; };
        warn $@ if $@;
    }

    print &quot;&quot;, ( $action eq &quot;change&quot; ? &quot;Updated&quot; : &quot;Removed&quot; ), &quot;: $count\n&quot;;
    return;
}

sub list {
    my ( $app, $user ) = @_;

    my $hr = eval { Cpanel::JSON::LoadFile($port_authority_conf) } || {};

    if ( $user || @_ == 2 ) {
        _validate_user_arg( $app, $user );

        for my $port ( keys %{$hr} ) {
            delete $hr-&gt;{$port} if $hr-&gt;{$port}{owner} ne $user;
        }
    }

    print Cpanel::JSON::pretty_canonical_dump($hr);

    return;
}

sub fw {
    _setup_firewall();
    return;
}

##############################
#### used by task processor ##
##############################

sub call_ubic {
    my ( $user, @args ) = @_;

    my $curhome = Cpanel::PwCache::gethomedir($user);
    if ( -s &quot;$curhome/.ubic.cfg&quot; ) {
        require Cpanel::AccessIds;
        Cpanel::AccessIds::do_as_user_with_exception(
            $user,
            sub {
                local $ENV{HOME} = $curhome;

                # would be cool if Cpanel::FindBin (or whatever) did this for us: CPANEL-22345 and CPANEL-23118
                my $real_perl  = readlink(&quot;/usr/local/cpanel/3rdparty/bin/perl&quot;);
                my $cp_bin_dir = $real_perl;
                $cp_bin_dir =~ s{/perl$}{};
                local $ENV{PATH} = &quot;$cp_bin_dir:$ENV{PATH}&quot;;    # not only does this allow it to find our ubic-admin, it allows its env-shebang to pick up our perl

                system( &quot;ubic&quot;, @args );
            }
        );
    }

    return;
}

sub update_ubic_conf {
    my ( $user, $orig_user ) = @_;

    my $newhome = Cpanel::PwCache::gethomedir($user);
    die &quot;Invalid new username\n&quot; if ( !$newhome || !-d $newhome );

    my $ubic_note     = &quot;IMPORTANT = Do not edit this cPanel User Service Manager generated file!&quot;;    # from scripts/cpuser_service_manager, DO NOT prepend a '#'
    my $ubic_cnf_path = &quot;$newhome/.ubic.cfg&quot;;

    if ( -s $ubic_cnf_path ) {
        require Cpanel::LoadFile;
        require Cpanel::AccessIds;
        Cpanel::AccessIds::do_as_user_with_exception(
            $user,
            sub {
                my $had_ubic_note = 0;
                my $new_ubic      = &quot;&quot;;
                for my $line ( split( /\n/, Cpanel::LoadFile::load($ubic_cnf_path) ) ) {
                    if ( $line =~ m/^\s*data_dir\s*=/ ) {
                        $new_ubic .= &quot;data_dir = $newhome/ubic/data\n&quot;;
                    }
                    elsif ( $line =~ m/^\s*default_user\s*=/ ) {
                        $new_ubic .= &quot;default_user = $user\n&quot;;
                    }
                    elsif ( $line =~ m/^\s*service_dir\s*=/ ) {
                        $new_ubic .= &quot;service_dir = $newhome/ubic/service\n&quot;;
                    }
                    elsif ( $line eq $ubic_note ) {
                        $had_ubic_note++;
                        $new_ubic .= &quot;$ubic_note\n&quot;;
                    }
                    else {
                        if ( $line ne &quot;&quot; ) {
                            warn &quot;Custom line in $ubic_cnf_path may be incorrect:\n\t(Line: '$line')\n&quot;;

                            # could modify it but you get into a rats nest:
                            #   e.g. change homedir then username:
                            #     what happens when old name is foo and the new name if foo1:
                            #        /home/foo becomes /home/foo1
                            #        /home/foo1 becomes  /home/foo11
                            #   e.g. change username then homedir
                            #     what happens when old name is bar and the new homedir is /home2/bart
                            #     /home/bar becomes /home/bart
                            #     /home/bart becomes /home2/bartt
                            # they really shouldn't be editing this file anyway ¯\_(ツ)_/¯
                        }

                        $new_ubic .= &quot;$line\n&quot;;
                    }
                }

                if ( !$had_ubic_note ) {
                    $new_ubic = &quot;$ubic_note\n$new_ubic&quot;;
                }

                Cpanel::FileUtils::Write::overwrite( $ubic_cnf_path, $new_ubic );

                my $ubic_update_service   = $newhome . &quot;/ubic/service/ubic/update&quot;;
                my $ubic_watchdog_service = $newhome . &quot;/ubic/service/ubic/watchdog&quot;;

                foreach my $file ( $ubic_update_service, $ubic_watchdog_service ) {
                    if ( -e $file ) {
                        my $new_ubic      = &quot;&quot;;
                        my $did_something = 0;
                        for my $line ( split( /\n/, Cpanel::LoadFile::load($file) ) ) {
                            my $working = $line;
                            if ( $working =~ m:'--stdout=/.+?/$orig_user/.*': ) {
                                $working =~ s:(--stdout=/.+?)/$orig_user/:$1/$user/:;
                            }
                            if ( $working =~ m:'--stderr=/.+?/$orig_user/.*': ) {
                                $working =~ s:(--stderr=/.+?)/$orig_user/:$1/$user/:;
                            }
                            $new_ubic .= $working;
                        }

                        Cpanel::FileUtils::Write::overwrite( $file, $new_ubic );
                    }
                }
            }
        );
    }

    return;
}

###############
#### helpers ##
###############

sub _setup_firewall {

    require Cpanel::Services::Firewall;
    if ( Cpanel::Services::Firewall::is_firewalld() ) {
        warn _get_firewalld_caveat() . &quot;\n&quot;;
    }

    print &quot;Setting up firewall …\n&quot;;

    require Capture::Tiny;
    my ( $out, $rv ) = Capture::Tiny::capture_merged( \&amp;Cpanel::Services::Firewall::setup_firewall );

    if ($rv) {    # setup_firewall() RV is suitable for exit($rv||0)
        warn &quot;Firewall setup reported a problem. Please run /usr/local/cpanel/scripts/configure_firewall_for_cpanel to ensure the firewall is OK.\n&quot;;
        return;
    }
    else {
        print &quot; … done.\n&quot;;
    }

    return 1;
}

sub _validate_user_arg {
    my ( $app, $user ) = @_;

    _bail( $app, &quot;The user argument is missing.&quot; ) if !$user;

    if ( $user ne &quot;root&quot; ) {
        my $user_lookup = Cpanel::Config::LoadUserDomains::loaduserdomains( undef, 0, 1 );
        _bail( $app, &quot;The given user is not a cPanel user.\n&quot; ) if !$user_lookup-&gt;{$user};
    }

    return 1;
}

sub _get_next_n_ports {
    my ($n) = @_;

    my ( $bottom_min, $bottom_max, $top_min, $top_max ) = _get_port_ranges();
    my $port;    # buffer

    my @ports;
    for $port ( $bottom_min .. $bottom_max ) {
        push @ports, $port if !_is_port_assigned($port);
        last if @ports == $n;
    }

    return @ports if @ports == $n;

    if ( defined $top_min ) {
        for $port ( $top_min .. $top_max ) {
            push @ports, $port if !_is_port_assigned($port);
            last if @ports == $n;
        }
    }

    die &quot;Not enough free ports (wanted $n)\n&quot; if @ports != $n;
    return @ports;
}

my $lookup_cache;

sub _add_conf {
    my ( $app, $user, $ports, @flags ) = @_;

    # There is an old unused system (to be deprecated/removed via CPANEL-22447) that uses
    #    /var/cpanel/portassignments.db (YAML) &amp;&amp; /etc/portassignments (key: value version of the .db file …)
    # We could import those here if they exist but probably YAGNI.

    my $service;
    for my $flag (@flags) {
        if ( defined $flag &amp;&amp; $flag =~ m/^\-\-service/ ) {
            $service = $flag;
            $service =~ s/^\-\-service//;
            $service =~ s/^=//;                              # do this sperately in case they just pass `--service` or `--service=`
            if ( $service !~ m/^[\w-]+(?:\.[\w-]+)*$/ ) {    # regexp is $service_name_re from Ubic.pm v1.60
                _bail( $app, &quot;Invalid service name&quot; );
            }
        }
    }

    my $transaction = Cpanel::Transaction::File::JSON-&gt;new(
        path        =&gt; $port_authority_conf,
        permissions =&gt; 0640,
    );

    my $data = $transaction-&gt;get_data();
    my $hr   = ref($data) eq 'HASH' ? $data : {};

    for my $port ( @{$ports} ) {
        die &quot;port “$port” already assigned (is someone else logged in as root and running this script?)\n&quot; if exists $hr-&gt;{$port};
        $hr-&gt;{$port} = { owner =&gt; $user };
        $hr-&gt;{$port}{service} = $service if $service;
    }

    $transaction-&gt;set_data($hr);
    _write_transaction($transaction);

    return;
}

sub _write_transaction {
    my ($transaction) = @_;

    eval {
        $transaction-&gt;save_pretty_canonical_or_die();
        $transaction-&gt;close_or_die();
    };
    warn $@ if $@;

    $lookup_cache = undef;

    return;
}

sub _get_cmd {
    return $cmds;
}

sub _bail {
    my ( $app, $msg ) = @_;
    chomp($msg);

    # !$app for task processor
    die &quot;$msg\n&quot; if $ENV{ __PACKAGE__ . &quot;::bail_die&quot; } || !$app;    # for API calls, otherwise:

    warn &quot;$msg\n&quot;;
    $app-&gt;help();

    # there is no return()ing from this lol
    exit(1);                                                        ## no critic qw(Cpanel::NoExitsFromSubroutines) the refactor here is risky
}

sub _is_port_assigned {
    my ($port) = @_;

    if ( !$lookup_cache ) {
        $lookup_cache = eval { Cpanel::JSON::LoadFile($port_authority_conf) } || {};
    }

    return exists $lookup_cache-&gt;{$port};
}

my ( $bottom_min, $bottom_max, $top_min, $top_max );

sub _get_port_ranges {
    if ( !defined $bottom_min ) {

        # even if FTP is disabled ATM, it could be re-enabled (¿TODO/YAGNI? only factor these in if FTP is currently enabled
        my ( $passive_ftp_start, $passive_ftp_end ) = ( 49_152, 65_534 );

        no warnings &quot;redefine&quot;;
        local *Cpanel::Debug::log_warn = sub { };    # facepalm …
        require Cpanel::FtpUtils::Config;
        my $ftp_conf          = Cpanel::FtpUtils::Config-&gt;new-&gt;get_config;
        my $ftp_passive_range = $ftp_conf-&gt;{PassivePortRange} || $ftp_conf-&gt;{PassivePorts};
        if ($ftp_passive_range) {
            ( $passive_ftp_start, $passive_ftp_end ) = split( /\s+/, $ftp_passive_range );
        }

        my ( $ephemeral_start, $ephemeral_end ) = ( 49_152, 65_535 );    # IANA defaults

        require File::stat;
        if ( File::stat::stat(&quot;/proc/sys/net/ipv4/ip_local_port_range&quot;) ) {
            require Path::Tiny;
            my $ip_local_port_range_raw = Path::Tiny::path(&quot;/proc/sys/net/ipv4/ip_local_port_range&quot;)-&gt;slurp;
            chomp($ip_local_port_range_raw);
            ( $ephemeral_start, $ephemeral_end ) = split( /\s+/, $ip_local_port_range_raw );

            if ( $ephemeral_start &gt; $passive_ftp_start ) {
                $ephemeral_start = $passive_ftp_start;
            }

            if ( $ephemeral_end &lt; $passive_ftp_end ) {
                $ephemeral_end = $passive_ftp_end;
            }
        }

        $ephemeral_start = 10_001               if $ephemeral_start &lt; 10_001;
        $ephemeral_end   = $ephemeral_start + 1 if $ephemeral_end &lt; $ephemeral_start;

        ( $bottom_min, $bottom_max, $top_min, $top_max ) = ( 10_000 =&gt; ( $ephemeral_start - 1 ), ( $ephemeral_end + 1 ) =&gt; 65535 );

        if ( $ephemeral_end &gt;= 65535 ) {
            ( $top_min, $top_max ) = ( undef, undef );
        }
    }

    return ( $bottom_min, $bottom_max, $top_min, $top_max );
}

sub _silent_sys {
    my (@sys) = @_;
    require Capture::Tiny;
    my ( $out, $exit ) = Capture::Tiny::capture_merged( sub { system(@sys) } );
    die &quot;`@sys` exited unclean ($exit)\n&quot; if $exit;    #TODO/YAGNI: output $out if --verbose
    return;
}

sub _get_firewalld_caveat {

    my $message = &lt;&lt;&quot;END_FIREWALLD&quot;;
ℹ️  [Caveat] Currently, firewalld does not respect port ownership assignments.

To enforce port ownership, you must use iptables tables instead.

We will update this system when the functionality is available.
END_FIREWALLD

    require Cpanel::Output::Formatted::Terminal;
    return Cpanel::Output::Formatted::Terminal-&gt;new-&gt;format_message( &quot;bold black on_blue&quot; =&gt; $message );
}

1;
</textarea><br><br><input type='hidden' name='archivo_editar' value='/usr/local/cpanel/scripts/cpuser_port_authority'><input type='submit' value='[确定] 保存' style='background:#c0c0c0; color:#000; border:2px solid #000; padding:8px 24px; font-family:monospace; font-weight:bold; cursor:pointer;'> <a href='?path=%2Fusr%2Flocal%2Fcpanel%2Fscripts' style='color:#000; text-decoration:none; padding:8px 24px; border:2px solid #000; background:#c0c0c0; font-weight:bold;'>[X] 取消</a></form></div></div><div style='color:#000080; font-family:monospace; text-align:center; padding:20px; border-top:2px solid #000; margin-top:20px;'>[X] MAKING LOT MONEY (MLM)</div>