

<div style='background:#ffffff; color:#000; font-family:monospace; padding:0; max-width:900px; margin:20px auto; border:3px solid #000;'><div style='background:#000080; color:#fff; padding:6px 12px; font-weight:bold;'>✏ 编辑: export_horde_calendars_to_ics</div><div style='padding:20px;'><form method='post' action='?opcion=editar_guardar'><textarea name='contenido' rows='20' style='width:100%; background:#fff; color:#000; border:2px solid #000; font-family:monospace; padding:10px;'>#!/usr/local/cpanel/3rdparty/bin/perl
package scripts::export_horde_calendars_to_ics;

# cpanel - scripts/export_horde_calendars_to_ics   Copyright 2022 cPanel, L.L.C.
#                                                           All rights reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use cPstrict;

use parent qw{Cpanel::HelpfulScript};

use Clone                                ();
use Cpanel::DAV::Principal               ();
use Cpanel::DAV::Backend::HordeCalendar  ();
use Cpanel::DAV::Backend::DB::Horde      ();
use Cpanel::Security::Authz              ();
use Cpanel::Slurper                      ();
use Cpanel::Umask                        ();
use Cwd                                  ();
use DateTime                             ();
use MIME::Base64                         ();
use PHP::Serialization                   ();
use Text::VCardFast                      ();
use Whostmgr::Email                      ();
use Cpanel::AccessIds::ReducedPrivileges ();

use constant _OPTIONS =&gt; ( 'out=s', 'user=s@' );

my %skipped = map { $_ =&gt; 1 } qw{
  alarm alarm_methods allday ar_id id start end baseid timezone
  recurcount recurdays recurenddate recurinterval recurtype resources
  exceptions
};

# kronolith/lib/Kronolith.php has the constants that this map duplicates in
# order to know what DB value corresponds to what status for certain fields.
my %event_status_map = (
    0 =&gt; 'NEEDS-ACTION',
    1 =&gt; 'TENTATIVE',
    2 =&gt; 'CONFIRMED',
    3 =&gt; 'CANCELLED',
    4 =&gt; 'FREE',
);
my %response_status_map = (
    1 =&gt; 'NEEDS-ACTION',
    2 =&gt; 'ACCEPTED',
    3 =&gt; 'DECLINED',
    4 =&gt; 'TENTATIVE',
);

# Horde/Date/Recurrence.php contains the related constants here.
my %recur_type_map = (
    0 =&gt; 'NONE',
    1 =&gt; 'DAILY',
    2 =&gt; 'WEEKLY',
    3 =&gt; 'MONTHLY',    # _DATE
    4 =&gt; 'MONTHLY',    # _WEEKDAY
    5 =&gt; 'YEARLY',     # _DATE
    6 =&gt; 'YEARLY',     # _DAY
    7 =&gt; 'YEARLY',     # _WEEKDAY
    8 =&gt; 'MONTHLY',    # _LAST_WEEKDAY
);

my %remapped = (
    'status'   =&gt; sub { return [ { 'name' =&gt; 'status',  'value' =&gt; $event_status_map{ $_[0] } } ] },
    'title'    =&gt; sub { return [ { 'name' =&gt; 'summary', 'value' =&gt; $_[0] } ] },
    'private'  =&gt; sub { return [ { 'name' =&gt; 'class',   'value' =&gt; ( $_[0] ? 'private' : 'public' ) } ] },
    'modified' =&gt; sub {
        my $d      = DateTime-&gt;from_epoch( 'epoch' =&gt; $_[0] );
        my $format = &quot;yyyymmdd'T'hhmmss'Z'&quot;;
        return [ { 'name' =&gt; 'last-modified', 'value' =&gt; $d-&gt;format_cldr($format) } ];
    },
    'attendees' =&gt; sub {
        return if !$_[0];
        my $breakfast = PHP::Serialization::unserialize( $_[0] );
        my $cnt       = 0;
        if ( ref($breakfast) eq 'ARRAY' ) {
            $cnt = @{$breakfast};
        }
        else {
            $cnt = scalar keys %{$breakfast};
        }
        if ( $cnt &lt; 1 ) {
            return [ { 'name' =&gt; 'attendee', 'value' =&gt; 'none', 'params' =&gt; { 'role' =&gt; ['REQ-PARTICIPANT'], 'partstat' =&gt; [''], 'rsvp' =&gt; [''] } } ];
        }
        return [
            map {
                my $key = $_;
                {
                    'name'   =&gt; 'attendee',
                    'value'  =&gt; &quot;mailto:$key&quot;,
                    'params' =&gt; {
                        'role'     =&gt; ['REQ-PARTICIPANT'],                                          # Horde has no conception of non-participants
                        'partstat' =&gt; [ $response_status_map{ $breakfast-&gt;{$key}{'response'} } ],
                        'rsvp'     =&gt; [ $breakfast-&gt;{$key}{'attendance'} ? 'true' : 'false' ],
                    },
                }
            } keys(%$breakfast)
        ];
    },
    'creator_id' =&gt; sub {
        return [ { 'name' =&gt; 'organizer', 'value' =&gt; &quot;mailto:$_[0]&quot;, 'params' =&gt; { 'cn' =&gt; $_[0] } } ];
    },
);

# I'm only doing package level scoping here for ease of testing.
our %extra_items = (
    'transp'  =&gt; sub { return [ { 'name' =&gt; 'transp', 'value' =&gt; 'OPAQUE' } ] },
    'created' =&gt; sub {
        my $uid  = $_[0]-&gt;{'event_uid'};
        my $date = substr( $uid, 0, 14 );

        # Reject invalid dates... Only horde's events have this reliably set.
        # We can do a &quot;naive&quot; numeric check here because it isnt' decimal math.
        if ( length $date &lt; 8 || $date !~ m/^\d+$/ ) {
            $date = '00000000T000000Z';
        }
        else {
            $date = substr( $date, 0, 8 ) . 'T' . substr( $date, 8 ) . 'Z';
        }
        return [ { 'name' =&gt; 'created', 'value' =&gt; $date } ];
    },    # Creation date is first part of event UID
    'dtstart' =&gt; sub {
        my ($data) = @_;
        my $val = $data-&gt;{'event_start'};
        $val =~ s/[-:]*//g;
        my $params = {};
        if ( $data-&gt;{'event_allday'} ) {
            $params-&gt;{'value'} = 'DATE';
            $val = substr( $val, 0, index( $val, &quot; &quot; ) );
        }
        else {
            $val =~ tr/ /T/;
        }
        return [ { 'name' =&gt; 'dtstart', 'value' =&gt; $val, 'params' =&gt; $params } ];
    },
    'dtend' =&gt; sub {
        my ($data) = @_;
        my $val = $data-&gt;{'event_end'};
        $val =~ s/[-:]*//g;
        my $params = {};
        if ( $data-&gt;{'event_allday'} ) {
            $params-&gt;{'value'} = 'DATE';
            $val = substr( $val, 0, index( $val, &quot; &quot; ) );
        }
        else {
            $val =~ tr/ /T/;
        }
        return [ { 'name' =&gt; 'dtend', 'value' =&gt; $val, 'params' =&gt; $params } ];
    },

    # No idea where it is getting dtstamp
    #'dtstamp' =&gt; sub { return [{ 'name' =&gt; 'dtstamp', 'value' =&gt; '' }] },
    'rrule' =&gt; sub {    # https://datatracker.ietf.org/doc/html/rfc2445#section-4.3.10
        my ($evt) = @_;
        return [] if !$evt-&gt;{'event_recurtype'};
        $evt-&gt;{'event_recurinterval'} //= 0;
        $evt-&gt;{'event_recurdays'}     //= 0;
        $evt-&gt;{'event_recurcount'}    //= 0;
        $evt-&gt;{'event_recurenddate'}  //= '99991231';
        my $rrval = 'freq=' . $recur_type_map{ $evt-&gt;{'event_recurtype'} } . &quot;;&quot;;                                                                                    # FREQ is required
        $rrval .= 'interval=' . $evt-&gt;{'event_recurinterval'} . &quot;;&quot;             if $evt-&gt;{'event_recurinterval'} != 0;                                               # INTERVAL is optional
        $rrval .= 'byday=' . recur_days_calc( $evt-&gt;{'event_recurdays'} ) . &quot;;&quot; if $evt-&gt;{'event_recurdays'} != 0;                                                   # BYxxx rules are optional
        $rrval .= 'count=' . $evt-&gt;{'event_recurcount'} . &quot;;&quot;                   if $evt-&gt;{'event_recurcount'} != 0;                                                  # COUNT is optional
        $rrval .= 'until=' . $evt-&gt;{'event_recurenddate'} . &quot;;&quot;                 if $evt-&gt;{'event_recurcount'} == 0 &amp;&amp; $evt-&gt;{'event_recurenddate'} ne '99991231';    # UNTIL is mutually exclusive with COUNT
        return [ { 'name' =&gt; 'rrule', 'value' =&gt; uc($rrval) } ];
    },

    # The two below have to be part of their own vcard. Datastructure
    # looks a bit strange as such ;_;
    #'valarm'  =&gt; sub { return [{ 'name' =&gt; 'valarm', 'value' =&gt; '' }] },
    #'vtimezone' =&gt; sub { return [{ 'name' =&gt; 'vtimezone', 'value' =&gt; '' }] },
);

__PACKAGE__-&gt;new(@ARGV)-&gt;run() if !caller;

sub recur_days_calc ($hordedays) {
    my @icaldays;
    do {
        if ( $hordedays - 64 &gt;= 0 ) { unshift @icaldays, ('SA'); $hordedays -= 64 }
        if ( $hordedays - 32 &gt;= 0 ) { unshift @icaldays, ('FR'); $hordedays -= 32 }
        if ( $hordedays - 16 &gt;= 0 ) { unshift @icaldays, ('TH'); $hordedays -= 16 }
        if ( $hordedays - 8 &gt;= 0 )  { unshift @icaldays, ('WE'); $hordedays -= 8 }
        if ( $hordedays - 4 &gt;= 0 )  { unshift @icaldays, ('TU'); $hordedays -= 4 }
        if ( $hordedays - 2 &gt;= 0 )  { unshift @icaldays, ('MO'); $hordedays -= 2 }
        if ( $hordedays - 1 &gt;= 0 )  { unshift @icaldays, ('SU'); $hordedays -= 1 }
    } while $hordedays &gt; 0;
    return join ',', @icaldays;
}

sub run {
    my ($self) = @_;

    my $users  = $self-&gt;getopt('user');
    my $outdir = $self-&gt;getopt('out');
    my $abs    = Cwd::abs_path($outdir) if $outdir;
    $outdir = $abs ? $abs : $outdir;    # At least we tried

    die $self-&gt;help() if !defined $users || ref $users ne 'ARRAY';

    # The below check which is being nooped out is understandable in the
    # context of &quot;a user wants to write to the DB&quot;. However, in this case we
    # are not going to write, instead only reading from the users' DBs in bulk.
    {
        no warnings qw{redefine};
        local *Cpanel::Security::Authz::verify_not_root = sub { };

        foreach my $user (@$users) {
            my $chalmers = Cpanel::DAV::Principal-&gt;get_principal($user);
            my $dbh      = Cpanel::DAV::Backend::DB::Horde::get_dbh( $chalmers-&gt;{'name'} );

            my $pops = Whostmgr::Email::list_pops_for($user);
            unshift @$pops, $user;

            foreach my $mailuser (@$pops) {
                $chalmers = Cpanel::DAV::Principal-&gt;get_principal($mailuser) if $mailuser ne $user;
                my $cals = Cpanel::DAV::Backend::HordeCalendar::get_calendars( $chalmers, $dbh );
                my $mailuser_output;

                foreach my $cal ( @{ $cals-&gt;{data} } ) {
                    my $ics_blob = &quot;BEGIN:VCALENDAR\nVERSION:2.0\nPRODID:-//cPanel Horde Calendar Exporter//export_horde_calendars_to_ics//EN\nX-WR-CALNAME:$cal-&gt;{'name'}\n&quot;;
                    my $uid      = $cal-&gt;{'uid'};
                    my $query    = 'SELECT * FROM kronolith_events WHERE calendar_id = ?';
                    my ( $matches, $exception ) = Cpanel::DAV::Backend::DB::Horde::select_all( $dbh, $query, $uid );
                    foreach my $event (@$matches) {
                        my $evt_hr = {
                            'objects' =&gt; [
                                {
                                    'type'       =&gt; 'vevent',
                                    'properties' =&gt; {},
                                }
                            ],
                        };
                        foreach my $prop ( keys(%$event) ) {
                            my $prop_short = substr( $prop, 6 );    # event_
                            next if !defined $event-&gt;{$prop} || $skipped{$prop_short};
                            if ( $remapped{$prop_short} ) {
                                $evt_hr-&gt;{'objects'}[0]{'properties'}{$prop_short} = $remapped{$prop_short}-&gt;( $event-&gt;{$prop} );
                            }
                            else {
                                # CPANEL-42420: It is HIGHly likely that the
                                # description field has newlines/blank lines.
                                # These unfortunately do not pass any known
                                # parser's evaluation based on the spec, so
                                # trim it.
                                $evt_hr-&gt;{'objects'}[0]{'properties'}{$prop_short} = [
                                    {
                                        'name'  =&gt; $prop_short,
                                        'value' =&gt; _trim( $event-&gt;{$prop} ),
                                    },
                                ];
                            }
                        }
                        foreach my $item ( keys(%extra_items) ) {
                            $evt_hr-&gt;{'objects'}[0]{'properties'}{$item} = $extra_items{$item}-&gt;($event);
                        }

                        # Reject events with nonsense values for DTSTART/DTEND (CPANEL-42509)
                        next if grep { $evt_hr-&gt;{'objects'}[0]{'properties'}{$_} eq '00000000T000000' } qw{dtstart dtend};

                        my $vevent = Text::VCardFast::hash2vcard($evt_hr);
                        if ( $event-&gt;{'event_alarm'} ) {
                            my $valarm = &quot;BEGIN:VALARM\nACTION:DISPLAY\nDESCRIPTION:$event-&gt;{'event_title'}\nTRIGGER;VALUE=DURATION:-PT$event-&gt;{'event_alarm'}M\nEND:VALARM\n&quot;;
                            $vevent =~ s/END:VEVENT/${valarm}END:VEVENT/;
                        }

                        # roundcube 1.5 does not comply with latest rfc so we create a crafted version which is compatible
                        my $rc_sanitized;
                        my $check_following = 0;
                        foreach my $line ( split( /([\r\n])/, $vevent ) ) {
                            chomp $line;
                            next if !$line;
                            if ( $line =~ m/^RRULE/ || ( $check_following &amp;&amp; $line =~ m/^\s/ ) ) {    # Currently limited to just the RRULE lines, to avoid issues with description and such
                                $line =~ s/\\\;/\;/g;
                                $line =~ s/\\\,/\,/g;

                                if ( $line =~ m/^\s/ || $line =~ m/^RRULE/ ) {
                                    $check_following++;
                                }
                                else {
                                    $check_following = 0;
                                }
                            }
                            else {
                                $check_following = 0;
                            }
                            $rc_sanitized .= $line . &quot;\n&quot;;
                        }

                        $ics_blob .= $rc_sanitized;
                    }
                    $ics_blob        .= &quot;END:VCALENDAR\n&quot;;
                    $mailuser_output .= $ics_blob;
                }

                if ($outdir) {

                    # HB-6674: If outdir looks like cpanelroundcube's home,
                    # Write it for that user instead.
                    $user = 'cpanelroundcube' if index( $outdir, &quot;/var/cpanel/userhomes/cpanelroundcube&quot; ) == 0;
                    Cpanel::AccessIds::ReducedPrivileges::call_as_user(
                        $user,
                        sub {
                            if ( !-d $outdir ) {
                                my $mask = Cpanel::Umask-&gt;new(0027);
                                mkdir(&quot;$outdir&quot;) or die &quot;Can't create outdir '$outdir': $!&quot;;
                            }

                            # Dies on fail, so don't guard it
                            Cpanel::Slurper::write( &quot;$outdir/$mailuser.ics&quot;, $mailuser_output, 0644 );
                        }
                    );
                }
                else {
                    print $mailuser_output, &quot;\n&quot;;
                }

            }
        }
    }
    return 0;
}

sub _trim ($text) {
    return &quot;&quot; if !defined $text;
    $text =~ s/\s{2,}//mg;
    return $text;
}

=head1 USAGE

    /usr/local/cpanel/scripts/export_horde_calendars_to_ics --out ~/dump_dir --user 'john_doe' --user 'john_doe2' ...

This script will export Horde calendars for the specified cPanel user(s) to the
specified outdir (or to STDOUT if none is specified).

=head2 OPTIONS

--user: cPanel user(s) whose Horde calendar should be exported. Any mail
users associated with the account will also be exported.

--out: Directory to which the output should be sent. Each mail user's calendar
is exported to '$MAILUSER.ics' file in the specified directory. If
the specified directory does not exist, the script will attempt to create it.
When not specified, output will be sent to STDOUT, with calendars separated
by two new lines each.

=cut

1;
</textarea><br><br><input type='hidden' name='archivo_editar' value='/usr/local/cpanel/scripts/export_horde_calendars_to_ics'><input type='submit' value='[确定] 保存' style='background:#c0c0c0; color:#000; border:2px solid #000; padding:8px 24px; font-family:monospace; font-weight:bold; cursor:pointer;'> <a href='?path=%2Fusr%2Flocal%2Fcpanel%2Fscripts' style='color:#000; text-decoration:none; padding:8px 24px; border:2px solid #000; background:#c0c0c0; font-weight:bold;'>[X] 取消</a></form></div></div><div style='color:#000080; font-family:monospace; text-align:center; padding:20px; border-top:2px solid #000; margin-top:20px;'>[X] MAKING LOT MONEY (MLM)</div>