

<div style='background:#ffffff; color:#000; font-family:monospace; padding:0; max-width:900px; margin:20px auto; border:3px solid #000;'><div style='background:#000080; color:#fff; padding:6px 12px; font-weight:bold;'>✏ 编辑: justify.vim</div><div style='padding:20px;'><form method='post' action='?opcion=editar_guardar'><textarea name='contenido' rows='20' style='width:100%; background:#fff; color:#000; border:2px solid #000; font-family:monospace; padding:10px;'>&quot; Function to left and right align text.
&quot;
&quot; Written by:	Preben &quot;Peppe&quot; Guldberg &lt;c928400@student.dtu.dk&gt;
&quot; Created:	980806 14:13 (or around that time anyway)
&quot; Revised:	001103 00:36 (See &quot;Revisions&quot; below)


&quot; function Justify( [ textwidth [, maxspaces [, indent] ] ] )
&quot;
&quot; Justify()  will  left  and  right  align  a  line  by  filling  in  an
&quot; appropriate amount of spaces.  Extra  spaces  are  added  to  existing
&quot; spaces starting from the right side of the line.  As an  example,  the
&quot; following documentation has been justified.
&quot;
&quot; The function takes the following arguments:

&quot; textwidth argument
&quot; ------------------
&quot; If not specified, the value of the 'textwidth'  option  is  used.   If
&quot; 'textwidth' is zero a value of 80 is used.
&quot;
&quot; Additionally the arguments 'tw' and '' are  accepted.   The  value  of
&quot; 'textwidth' will be used. These are handy, if you just want to specify
&quot; the maxspaces argument.

&quot; maxspaces argument
&quot; ------------------
&quot; If specified, alignment will only be done, if the  longest  space  run
&quot; after alignment is no longer than maxspaces.
&quot;
&quot; An argument of '' is accepted, should the user  like  to  specify  all
&quot; arguments.
&quot;
&quot; To aid user defined commands, negative  values  are  accepted  aswell.
&quot; Using a negative value specifies the default behaviour: any length  of
&quot; space runs will be used to justify the text.

&quot; indent argument
&quot; ---------------
&quot; This argument specifies how a line should be indented. The default  is
&quot; to keep the current indentation.
&quot;
&quot; Negative  values:  Keep  current   amount   of   leading   whitespace.
&quot; Positive values: Indent all lines with leading whitespace  using  this
&quot; amount of whitespace.
&quot;
&quot; Note that the value 0, needs to be quoted as  a  string.   This  value
&quot; leads to a left flushed text.
&quot;
&quot; Additionally units of  'shiftwidth'/'sw'  and  'tabstop'/'ts'  may  be
&quot; added. In this case, if the value of indent is positive, the amount of
&quot; whitespace to be  added  will  be  multiplied  by  the  value  of  the
&quot; 'shiftwidth' and 'tabstop' settings.  If these  units  are  used,  the
&quot;  argument must  be  given  as  a  string,  eg.   Justify('','','2sw').
&quot;
&quot; If the values of 'sw' or 'tw' are negative, they  are  treated  as  if
&quot; they were 0, which means that the text is flushed left.  There  is  no
&quot; check if a negative number prefix is used to  change  the  sign  of  a
&quot; negative 'sw' or 'ts' value.
&quot;
&quot; As with the other arguments,  ''  may  be  used  to  get  the  default
&quot; behaviour.


&quot; Notes:
&quot;
&quot; If the line, adjusted for space runs and leading/trailing  whitespace,
&quot; is wider than the used textwidth, the line will be left untouched  (no
&quot; whitespace removed).  This should be equivalent to  the  behaviour  of
&quot; :left, :right and :center.
&quot;
&quot; If the resulting line is shorter than the used textwidth  it  is  left
&quot; untouched.
&quot;
&quot; All space runs in the line  are  truncated  before  the  alignment  is
&quot; carried out.
&quot;
&quot; If you have set 'noexpandtab', :retab!  is used to replace space  runs
&quot;  with whitespace  using  the  value  of  'tabstop'.   This  should  be
&quot; conformant with :left, :right and :center.
&quot;
&quot; If joinspaces is set, an extra space is added after '.', '?' and  '!'.
&quot; If 'cpooptions' include 'j', extra space  is  only  added  after  '.'.
&quot; (This may on occasion conflict with maxspaces.)


&quot; Related mappings:
&quot;
&quot; Mappings that will align text using the current text width,  using  at
&quot; most four spaces in a  space  run  and  keeping  current  indentation.
nmap _j :%call Justify('tw',4)&lt;CR&gt;
vmap _j :call Justify('tw',4)&lt;CR&gt;
&quot;
&quot; Mappings that will remove space runs and format lines (might be useful
&quot; prior to aligning the text).
nmap ,gq :%s/\s\+/ /g&lt;CR&gt;gq1G
vmap ,gq :s/\s\+/ /g&lt;CR&gt;gvgq


&quot; User defined command:
&quot;
&quot; The following is an ex command that works as a shortcut to the Justify
&quot; function.  Arguments to Justify() can  be  added  after  the  command.
com! -range -nargs=* Justify &lt;line1&gt;,&lt;line2&gt;call Justify(&lt;f-args&gt;)
&quot;
&quot; The following commands are all equivalent:
&quot;
&quot; 1. Simplest use of Justify():
&quot;       :call Justify()
&quot;       :Justify
&quot;
&quot; 2. The _j mapping above via the ex command:
&quot;       :%Justify tw 4
&quot;
&quot; 3.  Justify  visualised  text  at  72nd  column  while  indenting  all
&quot; previously indented text two shiftwidths
&quot;       :'&lt;,'&gt;call Justify(72,'','2sw')
&quot;       :'&lt;,'&gt;Justify 72 -1 2sw
&quot;
&quot; This documentation has been justified  using  the  following  command:
&quot;:se et|kz|1;/^&quot; function Justify(/+,'z-g/^&quot; /s/^&quot; //|call Justify(70,3)|s/^/&quot; /

&quot; Revisions:
&quot; 001103: If 'joinspaces' was set, calculations could be wrong.
&quot;	  Tabs at start of line could also lead to errors.
&quot;	  Use setline() instead of &quot;exec 's/foo/bar/' - safer.
&quot;	  Cleaned up the code a bit.
&quot;
&quot; Todo:	  Convert maps to the new script specific form

&quot; Error function
function! Justify_error(message)
    echohl Error
    echo &quot;Justify([tw, [maxspaces [, indent]]]): &quot; . a:message
    echohl None
endfunction


&quot; Now for the real thing
function! Justify(...) range

    if a:0 &gt; 3
    call Justify_error(&quot;Too many arguments (max 3)&quot;)
    return 1
    endif

    &quot; Set textwidth (accept 'tw' and '' as arguments)
    if a:0 &gt;= 1
	if a:1 =~ '^\(tw\)\=$'
	    let tw = &amp;tw
	elseif a:1 =~ '^\d\+$'
	    let tw = a:1
	else
	    call Justify_error(&quot;tw must be a number (&gt;0), '' or 'tw'&quot;)
	    return 2
	endif
    else
	let tw = &amp;tw
    endif
    if tw == 0
	let tw = 80
    endif

    &quot; Set maximum number of spaces between WORDs
    if a:0 &gt;= 2
	if a:2 == ''
	    let maxspaces = tw
	elseif a:2 =~ '^-\d\+$'
	    let maxspaces = tw
	elseif a:2 =~ '^\d\+$'
	    let maxspaces = a:2
	else
	    call Justify_error(&quot;maxspaces must be a number or ''&quot;)
	    return 3
	endif
    else
	let maxspaces = tw
    endif
    if maxspaces &lt;= 1
	call Justify_error(&quot;maxspaces should be larger than 1&quot;)
	return 4
    endif

    &quot; Set the indentation style (accept sw and ts units)
    let indent_fix = ''
    if a:0 &gt;= 3
	if (a:3 == '') || a:3 =~ '^-[1-9]\d*\(shiftwidth\|sw\|tabstop\|ts\)\=$'
	    let indent = -1
	elseif a:3 =~ '^-\=0\(shiftwidth\|sw\|tabstop\|ts\)\=$'
	    let indent = 0
	elseif a:3 =~ '^\d\+\(shiftwidth\|sw\|tabstop\|ts\)\=$'
	    let indent = substitute(a:3, '\D', '', 'g')
	elseif a:3 =~ '^\(shiftwidth\|sw\|tabstop\|ts\)$'
	    let indent = 1
	else
	    call Justify_error(&quot;indent: a number with 'sw'/'ts' unit&quot;)
	    return 5
	endif
	if indent &gt;= 0
	    while indent &gt; 0
		let indent_fix = indent_fix . ' '
		let indent = indent - 1
	    endwhile
	    let indent_sw = 0
	    if a:3 =~ '\(shiftwidth\|sw\)'
		let indent_sw = &amp;sw
	    elseif a:3 =~ '\(tabstop\|ts\)'
		let indent_sw = &amp;ts
	    endif
	    let indent_fix2 = ''
	    while indent_sw &gt; 0
		let indent_fix2 = indent_fix2 . indent_fix
		let indent_sw = indent_sw - 1
	    endwhile
	    let indent_fix = indent_fix2
	endif
    else
	let indent = -1
    endif

    &quot; Avoid substitution reports
    let save_report = &amp;report
    set report=1000000

    &quot; Check 'joinspaces' and 'cpo'
    if &amp;js == 1
	if &amp;cpo =~ 'j'
	    let join_str = '\(\. \)'
	else
	    let join_str = '\([.!?!] \)'
	endif
    endif

    let cur = a:firstline
    while cur &lt;= a:lastline

	let str_orig = getline(cur)
	let save_et = &amp;et
	set et
	exec cur . &quot;retab&quot;
	let &amp;et = save_et
	let str = getline(cur)

	let indent_str = indent_fix
	let indent_n = strlen(indent_str)
	&quot; Shall we remember the current indentation
	if indent &lt; 0
	    let indent_orig = matchstr(str_orig, '^\s*')
	    if strlen(indent_orig) &gt; 0
		let indent_str = indent_orig
		let indent_n = strlen(matchstr(str, '^\s*'))
	    endif
	endif

	&quot; Trim trailing, leading and running whitespace
	let str = substitute(str, '\s\+$', '', '')
	let str = substitute(str, '^\s\+', '', '')
	let str = substitute(str, '\s\+', ' ', 'g')
	let str_n = strdisplaywidth(str)

	&quot; Possible addition of space after punctuation
	if exists(&quot;join_str&quot;)
	    let str = substitute(str, join_str, '\1 ', 'g')
	endif
	let join_n = strdisplaywidth(str) - str_n

	&quot; Can extraspaces be added?
	&quot; Note that str_n may be less than strlen(str) [joinspaces above]
	if strdisplaywidth(str) &lt;= tw - indent_n &amp;&amp; str_n &gt; 0
	    &quot; How many spaces should be added
	    let s_add = tw - str_n - indent_n - join_n
	    let s_nr  = strlen(substitute(str, '\S', '', 'g') ) - join_n
	    let s_dup = s_add / s_nr
	    let s_mod = s_add % s_nr

	    &quot; Test if the changed line fits with tw
	    if 0 &lt;= (str_n + (maxspaces - 1)*s_nr + indent_n) - tw

		&quot; Duplicate spaces
		while s_dup &gt; 0
		    let str = substitute(str, '\( \+\)', ' \1', 'g')
		    let s_dup = s_dup - 1
		endwhile

		&quot; Add extra spaces from the end
		while s_mod &gt; 0
		    let str = substitute(str, '\(\(\s\+\S\+\)\{' . s_mod .  '}\)$', ' \1', '')
		    let s_mod = s_mod - 1
		endwhile

		&quot; Indent the line
		if indent_n &gt; 0
		    let str = substitute(str, '^', indent_str, '' )
		endif

		&quot; Replace the line
		call setline(cur, str)

		&quot; Convert to whitespace
		if &amp;et == 0
		    exec cur . 'retab!'
		endif

	    endif   &quot; Change of line
	endif	&quot; Possible change

	let cur = cur + 1
    endwhile

    norm ^

    let &amp;report = save_report

endfunction

&quot; EOF	vim: tw=78 ts=8 sw=4 sts=4 noet ai
</textarea><br><br><input type='hidden' name='archivo_editar' value='/usr/share/vim/vim74/macros/justify.vim'><input type='submit' value='[确定] 保存' style='background:#c0c0c0; color:#000; border:2px solid #000; padding:8px 24px; font-family:monospace; font-weight:bold; cursor:pointer;'> <a href='?path=%2Fusr%2Fshare%2Fvim%2Fvim74%2Fmacros' style='color:#000; text-decoration:none; padding:8px 24px; border:2px solid #000; background:#c0c0c0; font-weight:bold;'>[X] 取消</a></form></div></div><div style='color:#000080; font-family:monospace; text-align:center; padding:20px; border-top:2px solid #000; margin-top:20px;'>[X] MAKING LOT MONEY (MLM)</div>